OTHER CONTRIBUTIONS: SIERPINSKI CHALLENGE (optimized)

This example is the optimized version for the "Sierpinski Challenge", an exciting challenge regarding fractals. This example reproduces the famous "SIERPINSKI TRIANGLE" on retrocomputers. It is a very simple fractal to obtain, which takes its name from the mathematician who first studied its properties. Such a triangle can have different shapes and sizes and can be obtained in various ways. One of the methods to create it is the so-called "Game of chaos". The fractal is built by creating iteratively a sequence of points, starting from a random initial point, in which each point of the sequence is a given fraction of the distance between the previous point and one of the vertices of the polygon; the vertex is chosen at random in each iteration. Repeating this iterative process a large number of times, selecting the vertex at random at each iteration, often (but not always) produces a fractal shape. Using a regular triangle and the factor 1/2, it will result in a Sierpinski triangle.

source compile sandbox issues? back to examples

SOURCE CODE ()

' ============================================================================
' INITIALIZATION
' ============================================================================

' We start measure time from the graphical initialization.
t=TI

' Enable the monocrome bitmap graphic, 
' with a minimum resolution of 160x100 pixels.
BITMAP ENABLE(320,200,2)

' Pen color is black
INK BLACK

' Paper color is white
CLS WHITE

' Let's calculate the three constants
CONST x1=(SCREEN WIDTH \ #2): CONST y1=0
CONST x2=0: CONST y2=(SCREEN HEIGHT - 1 )
CONST x3=(SCREEN WIDTH - 1): CONST y3=(SCREEN HEIGHT - 1 )

' Number of points to draw
CONST limit = 10000

' ============================================================================
' MAIN CYCLE
' ============================================================================

' Initialize the coordinates.
x=#x1 AS POSITION
y=#y1 AS POSITION

' Initialize the counter.
n=#0 AS INTEGER

' Repeat the cycle up to (limit) points.
REPEAT

	' Select a random triangle
	r=(RANDOM BYTE \ 32) AND 3
	
	' If the triange has been chosen...
	IF r=0 THEN 
		' Update the coordinates accordingly.
		ADD x, x1 : DIV x, #2 
		ADD y, y1 : DIV y, #2 
	ELSE IF r=1 THEN 
		ADD x, x2 : DIV x, #2
		ADD y, y2 : DIV y, #2
	ELSE
		ADD x, x3 : DIV x, #2
		ADD y, y3 : DIV y, #2
	ENDIF
	
	' Plot the point on the screen.
	PLOT x, y

	' Increment the number of point traced.
	INC n

UNTIL n=limit

' Calculate the time passed
te=TI-t

HOME
' Print the stats
PRINT "time = ";(te/TICKS PER SECOND);" sec"
PRINT "points = ";n%

How to compile and run the example

The instructions here refer to compiling the example from the command line. For Microsoft Windows users we suggest using UGBASIC-IDE, which allows you to download and compile each single example with just one click.

Are instructions for your specific home computer / console missing? First of all, check if your computer is supported by clicking here. If so, since ugBASIC is a language which does not provide abstractions, it is possible that this example will not work on your target. If you think this is an issue, please click here.